Hive-DML(Data Manipulation Language)数据操作语言

大数据真有意思 2020-05-26

152

https://cwiki.apache.org/confluence/display/HIVE

Hive-数据导入

向表中装载数据（Load）

语法

hive>load data [local] inpath '/opt/module/datas/student.txt' [overwrite] into table student [partition (partcol1=val1,…)];

（1）load data:表示加载数据

（2）local:表示从本地加载数据到hive表；否则从HDFS加载数据到hive表

（3）inpath:表示加载数据的路径

（4）into table:表示加载到哪张表

（5）student:表示具体的表

（6）overwrite:表示覆盖表中已有数据，否则表示追加

（7）partition:表示上传到指定分区

实操案例

创建一张表

hive (default)> create table student(id string, name string) row format delimited fields terminated by '\t';

加载本地文件到hive

hive (default)> load data local inpath '/opt/module/datas/student.txt' into table default.student;

加载HDFS文件到hive中

上传文件到HDFS

hive (default)> dfs -put opt/module/datas/student.txt user/xxx/hive;

加载HDFS上数据

hive (default)>load data inpath '/user/xxx/hive/student.txt' into table default.student;

加载数据覆盖表中已有的数据

上传文件到HDFS

hive (default)> dfs -put opt/module/datas/student.txt user/xxx/hive;

加载数据覆盖表中已有的数据

hive (default)>load data inpath '/user/xxx/hive/student.txt' overwrite into table default.student;

通过查询语句向表中插入数据（Insert）

1.创建一张分区表

hive (default)> create table student(id string, name string) partitioned by (month string) row format delimited fields terminated by '\t';

2.基本插入数据

hive (default)> insert into table  student partition(month='202001') values('1004','wangwu');

3.基本模式插入（根据单张表查询结果）

hive (default)> insert overwrite table student partition(month='202002')
select id, name from student where month='202001';

4.多插入模式（根据多张表查询结果）

hive (default)> from student
insert overwrite table student2 partition(month='202003')
select id, name where month'202002'
insert overwrite table student3 partition(month='202001')
select id, name where month='202002';

查询语句中创建表并加载数据（as select）

详见Hive-DDL(Data Definition Language)数据定义-创建表。

根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3
as select id, name from student;

创建表时通过location指定加载数据路径

1.创建表，并指定在hdfs上的位置

hive (default)> create table if not exists student5(
    id int, name string 
row format delimited fields terminated by '\t'
location '/user/hive/warehouse/student5';

2.上传数据到hdfs上

hive (default)> dfs -put opt/module/datas/student.txt  user/hive/warehouse/student5;

3）查询数据

hive (default)> select * from student5;

import数据到指定hive表中

先用export导出后，再将数据导入。

hive (default)> export table student to '/export/student_export/';
hive (default)> import table student4 from '/export/student_export';

注意：import目标表必须为不存在的表。

Hive-数据导出

insert导出

1.将查询的结果导出到本地

hive (default)> insert overwrite local directory '/opt/module/datas/export/student'
select * from student;

2.将查询的结果格式化导出到本地

hive (default)> insert overwrite local directory '/opt/module/datas/export/student1'
ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' COLLECTION ITEMS TERMINATED BY '#'
select * from student;

3.将查询的结果导出到HDFS上(没有local)

hive (default)> insert overwrite directory '/user/atguigu/hive/warehouse/student2'
ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' COLLECTION ITEMS TERMINATED BY '\n'
select * from student;

Hadoop命令导出到本地

hive (default)> dfs -get /user/hive/warehouse/student/month=202001/123456_0  /opt/module/datas/export/student3.txt;

hive shell 命令导出

基本语法：（hive -f/-e 执行语句或者脚本 > file）

$ bin/hive -e 'select * from default.student;' > /opt/module/datas/export/student4.txt;

export导出到HDFS上

hive (default)> export table default.student to '/user/hive/warehouse/export/student';

sqoop导出

清除表中数据（truncate）

注意：Truncate只能删除管理表，不能删除外部表中数据

hive (default)> truncate table student;

【END】

数据库

文章转载自大数据真有意思，如果涉嫌侵权，请发送邮件至：contact@modb.pro进行举报，并提供相关证据，一经查实，墨天轮将立刻删除相关内容。

Hive-DML(Data Manipulation Language)数据操作语言

评论