解决Oracle用户密码过期，快速恢复原有密码的问题

数据库驾驶舱 2024-04-05

257

背景：

在Oracle数据库管理中，用户密码过期是一个常见的问题。当用户密码过期时，可能会导致用户无法登录数据库，给业务带来不便甚至影响正常运行。因此，需要快速有效地处理密码过期问题，以确保用户能够尽快恢复正常登录状态。

快速处理方法解析：

使用下面脚本快速恢复密码

--解锁用户，并重置为原有密码


<<unexpire>>
declare
  CONST_USERNAME constant varchar2(128) := '用户名';
  v_unexpire_cmd varchar2(4000);
begin


  execute immediate ' alter user ' || CONST_USERNAME || ' account unlock';


  select 'alter user ' || name || q'< identified by values '>' || spare4 || ';' || password || q'<'>' into v_unexpire_cmd
  from sys.user$ 
  where name = unexpire.const_username;


  execute immediate v_unexpire_cmd;


end unexpire;
/

重置为原有密码有两种方式：

查询1：仅提取了user$表中的password字段。这个字段通常包含用户密码的加密哈希值。例如，F894844C34402B67是SCOTT用户密码的加密形式。这种加密是基于Oracle的早期密码管理策略，通常使用较简单的加密算法。


select 'alter user '||name||' identified by values '''||password||''';' from user$ where name='SCOTT';


'ALTERUSER'||NAME||'IDENTIFIEDBYVALUES'''||PASSWORD||''';'
--------------------------------------------------------------------------------------------------
alter user SCOTT identified by values 'F894844C34402B67';




查询2：展示了Oracle 11g引入的增强密码特性。这里，spare4字段存储了一个更加复杂的密码表示，它包含了盐值（salt）和密码哈希的组合，以及使用了更加强化的哈希算法，而后面跟随的是原始的密码哈希，以便向后兼容。
select 'alter user ' || name || ' identified by values ''' || spare4 || ';' || password || ''';' from sys.user$ where name = 'SCOTT';


'ALTERUSER'||NAME||Q'<IDENTIFIEDBYVALUES'>'||SPARE4||';'||PASSWORD||Q'<'>'
--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
alter user SCOTT identified by values 'S:0881738420DA94272A0EDC1848C966DF32F820B8434DFBAF39EEB497A850;F894844C34402B67';

防止以后密码过期的方法：

方法1：将用户的profile改成无限制


alter profile default limit PASSWORD_LIFE_TIME unlimited;
alter profile default limit PASSWORD_LOCK_TIME unlimited;
alter profile default limit PASSWORD_GRACE_TIME unlimited;




方法2：或者新建一个profile，并设置为新profile


<<unexpire>>
declare
  CONST_USERNAME constant varchar2(128) := '用户名';
  CONST_NEW_PROFILE_NAME constant varchar2(128) := 'PASSWORD_LIFE_UNLIMITED';
  
  v_existing_profile varchar2(128);
  v_sql varchar2(32767);
begin
  select du.profile into v_existing_profile
  from dba_users du
  where du.username = CONST_USERNAME;
  
  v_sql := ' create profile ' || CONST_NEW_PROFILE_NAME || ' limit ';
  
  for v_row in (select dp.resource_name, dp.limit
                from dba_profiles dp
                where dp.profile = v_existing_profile
                  and dp.resource_name <> 'PASSWORD_LIFE_TIME')
  loop
    v_sql := v_sql || v_row.resource_name || ' ' || v_row.limit || ' ';
  end loop;


  v_sql := v_sql || 'PASSWORD_LIFE_TIME UNLIMITED';
                
  declare
    profile_already_exists exception;
    pragma exception_init(profile_already_exists, -2379);
  begin
    execute immediate v_sql;
  exception when profile_already_exists then 
    null;
  end;
  
  execute immediate 'alter user ' || CONST_USERNAME || ' profile ' || CONST_NEW_PROFILE_NAME;
end unexpire;
/

总结：

密码过期是Oracle数据库管理中常见的问题，但通过上述快速处理方法，可以有效地解决。解锁用户账号、重置用户密码、调整用户profile等步骤可以快速恢复用户的登录权限，确保数据库用户能够顺利访问数据库，维护业务的正常运行。

欢迎关注我们的公众号，获取更多技术分享与经验交流。

oracle oracle数据库

文章转载自数据库驾驶舱，如果涉嫌侵权，请发送邮件至：contact@modb.pro进行举报，并提供相关证据，一经查实，墨天轮将立刻删除相关内容。

解决Oracle用户密码过期，快速恢复原有密码的问题

评论