Power Query M语言实例 | 表中的新旧值替换

在实际的数据清洗与转换过程中,替换是必不可少的动作,并且很多时候需面临各类复杂的替换,因此与替换相关的操作值得花时间去深究。

Table.ReplaceValue()

Table.ReplaceValue(
  table as table, 
  oldValue as any,     //Y
  newValue as any,     //Z
  replacer as function,   //分ReplaceText或ReplaceValue两种情形
  columnsToSearch as list   //X
) as table

1

●

基础语法

= Table.ReplaceValue(源,null,"0",Replacer.ReplaceValue,{"城市"})

= Table.ReplaceValue(源,null,"0",Replacer.ReplaceValue,{"省份", "城市"})

= Table.ReplaceValue(源,null,each [省份],Replacer.ReplaceValue,{"城市"})

//ch9-053
let
    源 = Excel.CurrentWorkbook(){[Name="表6"]}[Content],
    替换 = Table.ReplaceValue(源,null,each [省份],Replacer.ReplaceValue,{"城市"})
in
    替换

//ch9-054
let
    A = Excel.CurrentWorkbook(){[Name="表6A"]}[Content],
   源 = Excel.CurrentWorkbook(){[Name="表6"]}[Content],
   替换 = Table.ReplaceValue(源,
            null,
            each A{[省份=[省份]]}[城市],
            Replacer.ReplaceValue,
            {"城市"}
           )
in
   替换

= Table.ReplaceValue(源,null,each [省份],(x,y,z)=>if x is null then z else x,{"城市"})

//ch9-055
let
  源 = Excel.CurrentWorkbook(){[Name="表6"]}[Content],
  替换 = Table.ReplaceValue(
    源,
            null,
            each [省份],
            (x,y,z)=>if x is null then z else x,
            {"城市"}
           )
in
  替换

2

●

进阶语法

3

●

进阶应用

//ch9-056
let
  源 = Excel.CurrentWorkbook(){[Name="表6"]}[Content],
  替换 = Table.ReplaceValue(
    源,
             {"北京","上海","广州","深圳"},
             "一线",
             (x,y,z)=> if List.Contains(y,x) then z else x,
             {"省份", "城市"}
           )
in
  替换

//ch9-057
let
  源 = Excel.CurrentWorkbook(){[Name="表3"]}[Content],
  取一部分数据 = Table.AlternateRows(源,1,2,1),
  替换 = Table.ReplaceValue(
  取一部分数据,
             each {[Q1],[Q2]},
             "(A+)",
             (x,y,z)=> if List.Sum(y)>185 then x&z else x,
             { "城市"}
           )
in
  替换

//ch9-058
let
  源 = Excel.CurrentWorkbook(){[Name="表3"]}[Content],
  取一部分数据 = Table.AlternateRows(源,1,2,1),
  替换 = Table.ReplaceValue(
  取一部分数据,
             each [Q1]+[Q2],
             "(A+)",
             (x,y,z)=> if y>185 then x&z else x,
             {"城市"}
           )
in
  替换

//ch9-059
let
  源 = Excel.CurrentWorkbook(){[Name="表3"]}[Content],
  取一部分数据 = Table.AlternateRows(源,1,2,1),
  类型 = Table.TransformColumnTypes(取一部分数据,{{"排名", type text}}),
  替换 = Table.ReplaceValue(
  类型,
             each {[Q1],[Q2]},
             {"(A+)","(A)","(A-)"},
             (x,y,z)=> if List.Sum(y)>185 then x&z{0} 
                       else if List.Sum(y)>165 then x&z{1} else x&z{2},
             {"城市","排名"}
           )
in
  替换

Table.ReplaceErrorValues()

Table.ReplaceErrorValues(
  table as table, 
  errorReplacement as list
) as table

//ch9-060
let 
    a= #table(
        {"运单","客户"},
        {{"YD001","王2"},{"YD003","张3"}, {"YD005","李"&4}}
       )
in
    a

= Table.ReplaceErrorValues(a, {{"客户", "李4"}})

Table.Transpose()

Table.Transpose(
  table as table, 
  optional columns as any
) as table

//ch9-061
let
源 = Excel.CurrentWorkbook(){[Name="表1"]}[Content],
降级 = Table.DemoteHeaders(源),
转置 = Table.Transpose(降级)
in
转置

参考书籍

本书以M语言中高频使用的函数为依托，通过一组简单、易于理解的数据源并且方便读者动手实践的方式，循序渐进地讲解，以此来演绎上百个实用案例，从而有效地实现本书的写作目标：“让所有的读者一个月之内对M语言函数有一个直观、清晰的了解，并能轻松上手”。