VBA 字典 如果遇到这样的数据是退还是不退？

Sub GetData(control As IRibbonControl)
    Dim Dic As Object
    Dim intX&, intY&, iRow&, iCol&, y&, x&
    Dim aData, aRes, strName$
    aData = Range("A1").CurrentRegion '获取数据来源
    Range(Range("k1"), Cells(1, Columns.Count)).EntireColumn.Clear '清除K列以后的数据
    iCol = 1: iRow = 1: x = 1 '初始化数据
    ReDim aRes(1 To UBound(aData), 1 To iCol) '定义结果数组大小
    Set Dic = CreateObject("Scripting.Dictionary") '后期绑定字典
    For intX = LBound(aData) To UBound(aData) '遍历循环数据源,从最小下标开始
        strName = aData(intX, 1) '赋值
        If strName <> "" Then
            If strName = "姓名" Then '判断是否为姓名
                x = intX '获取所在数据源行位置
                For intY = 2 To UBound(aData, 2)
                    If aData(intX, intY) <> "" Then
                        If Not Dic.exists(aData(intX, intY)) Then '判断标题关键字是否存在于字典中
                            iCol = iCol + 1 '累加数据列位置
                            Dic(aData(intX, intY)) = iCol '标题关键字对应的条目为结果数组列位置
                            If iCol > UBound(aRes, 2) Then ReDim Preserve aRes(1 To UBound(aRes), 1 To iCol) '调整结果数组大小
                            aRes(1, iCol) = aData(intX, intY) '结果数组写入标题
                        End If
                    End If
                Next
            Else
                iRow = iRow + 1 '结果数组行位置累加
                aRes(iRow, 1) = aData(intX, 1) '写入名字
                For intY = 2 To UBound(aData, 2)
                    If aData(x, intY) <> "" Then
                        y = Dic(aData(x, intY)) '获取标题关键字的条目
                        aRes(iRow, y) = aData(intX, intY) '写入结果数组
                    End If
                Next
            End If
        End If
    Next
    aRes(1, 1) = "姓名"
    With Range("K1").Resize(iRow, iCol)
        .Value = aRes '输出内容
        .Font.Name = "微软雅黑" '修改字体
        .Borders.ColorIndex = 23 '添加边框
    End With
    Set Dic = Nothing '释放字典内存
End Sub